Arduino UNO et lecteur RFID RC422 – Un tutoriel complet

21/02/2023 /pargdfgdfg fgdgd / in Uncategorized

RFID Schema de principeObjectifs

  • Comprendre le fonctionnement et l’utilité de la technologie RFID
  • Savoir les caractéristiques techniques du module RFID RC522
  • Se familiariser à l’utilisation du module RC522 dans un projet du contrôle d’accès
  • Se familiariser à l’utilisation de la librairie dédiée au module RC522
  • Autres astuces pratiques

RFID : Comment ça marche ?

Le présent projet est une introduction à une série des projets qui abordent la technologie RFID. RFID «Radio-Frequency IDentification» est une technologie pour laquelle les données numériques codées dans des étiquettes RFID ou « tags ». Elles sont capturées par un lecteur via des ondes radio. La RFID est similaire aux codes barres dans la mesure où les données d’une étiquette sont capturées par un appareil qui stocke les données dans une base de données. La RFID présente toutefois plusieurs avantages par rapport aux systèmes utilisant un logiciel de suivi des actifs de codes barres. En effet, le code barre nécessite  un scanner optique.

 

La RFID appartient à un groupe de technologies appelées Automatic Identification and Data Capture (AIDC). Les méthodes AIDC identifient automatiquement les objets, collectent des données les saisissent directement dans des systèmes informatiques avec une intervention humaine minime. Les méthodes RFID utilisent des ondes radio pour y parvenir. À un niveau simple, les systèmes RFID se composent de trois composants: une étiquette RFID « RFID tag », un lecteur RFID et une antenne. Les étiquettes RFID contiennent un circuit intégré et une antenne, qui permettent de transmettre des données au lecteur RFID. Le lecteur convertit ensuite les ondes radio en une forme de données plus utilisable. Les informations collectées à partir des étiquettes sont ensuite transférées via une interface de communication vers un système informatique hôte pour les traitements ultérieurs.

La technologie RFID basée sur des transferts d’énergie par liaison radio en utilisant des antennes électromagnétiques. Pour la mettre en application, il est nécessaire de disposer de marqueurs (étiquettes, tags ou puces RFID) et d’un lecteur RFID. Lire la suite…

Applications (voir la vidéo en bas de la page)

  • Gestion de l’inventaire
  • Suivi des actifs
  • Suivi du personnel
  • Contrôle de l’accès aux zones restreintes
  • Badge d’identification
  • Gestion de la chaîne logistique
  • Prévention de la contrefaçon (par exemple dans l’industrie pharmaceutique)
  • Plus de détails

Tout savoir sur le module RFID RC522 à 13.56MHz

 

Le module est un lecteur de la puce RFID basé sur le circuit MFRC522 à faible coût est facile à utiliser. Il peut être utilisé dans une large gamme d’application. Le MFRC522 est un circuit intégré de lecture / écriture hautement intégré pour la communication sans contact à 13,56 MHz. Ci-dessous les caractéristiques du module:

  • Basé sur le circuit MFRC522
  • Fréquence de fonctionnement: 13,56 MHz
  • Tension d’alimentation: 3.3V
  • Courant: 13-26mA
  • Portée de lecture: Environ 3 cm avec la carte et le porte-clés fournis
  • Interface de communication : SPI
  • Taux de transfert de données maximum: 10 Mbit / s
  • Dimensions: 60mm × 39mm
  • MFRC522 Datasheet

 

Fonctionnement du projet contrôle d’accès par badge avec Arduino

RFID Contrôle d'accès par badge avec Arduino

L’application consiste l’ouverture d’une porte en utilisant un badge. Le lecteur RFID couplé à la carte Arduino permet de détecter un badge enregistré ou non. Lorsque l’utilisateur est reconnu, le système déclenche l’ouverture de la porte ou une alarme dans le cas échéant. L’utilisateur à droit de trois tentatives. Le nombre de tentatives est ajustable par le programme Arduino. Ci-dessous les éléments constituant le projet ainsi leurs fonctionnements.

RFID-RC522 : Lecteur du badge

Carte Arduino : Elle est couplée avec le lecteur RFID. Elle permet de détecter la présence du badge, reconnaitre son identifiant (code du badge). Elle sert également à activer l’ouverture de la porte ou l’alarme

LED verte : Voyant indiquant l’ouverture de la porte. La LED s’allume pendant une seconde lorsqu’un badge reconnu est détecté. Elle reste éteinte dans le cas contraire

LED rouge : Voyant indiquant la détection d’un Fau badge (identifiant non reconnu du badge). La LED rouge s’allume pendant une seconde puis s’éteint pour chaque fausse détection. Lorsque le nombre de tentatives est atteint, la LED rouge clignote en boucle infinie en état d’alarme. Aucune moyenne n’est possible pour réactiver le système à part la réinitialisation de la carte Arduino.

Note : On peut ajouter un bouton de réinitialisation (non lisible pour l’utilisation) dédié à la désactivation de l’alarme.

RS232 : Le système communique l’état de la porte ou la présence de l’alarme par la liaison RS232. On affiche « Ouverture de la porte » lorsque la LED verte est allumée. Et « Alarme » en boucle lorsque le nombre de tentatives est attient.

Câblage des composants

  • LED rouge: D2
  • LED verte:  D3

RFID-ARDUINO:

SignalRFID-RC522ARDUINO
RST/ResetRSTD9
SPI SSSDA(SS)D10
SPI MOSIMOSID11
SPI MISOMISOD12
SPI SCKSCKD13

Comment lire l’ID d’un badge ?

Le module RFID est accompagné de deux badges de formes différentes (voir l’image ci-dessus) : l’un se forme d’une carte et l’autre d’une clé. Pour l’instant on ne connaît pas les identifiants de chacun d’entre eux. La première étape consiste à reconnaitre les ID pour les opérations à venir. Nous avons besoin de télécharger la librairie RFID (disponible ICI). On considère le même schéma de câblage. Ci-dessous les étapes importantes de déclaration, initialisation, lecture et affichage de l’ID d’un badge.

1- Déclaration

#include <SPI.h> // SPI
#include <MFRC522.h> // RFID
#define SS_PIN 10
#define RST_PIN 9
    
// Déclaration 
MFRC522 rfid(SS_PIN, RST_PIN); 
// Tableau contentent l'ID
byte nuidPICC[4];

2- Initialisation

void setup() 
{ 
  // Init RS232
  Serial.begin(9600);
  // Init SPI bus
  SPI.begin(); 
  // Init MFRC522 
  rfid.PCD_Init(); 
}

3- Attente d’un nouveau badge

void loop() 
{
  // Initialisé la boucle si aucun badge n'est présent 
  if ( !rfid.PICC_IsNewCardPresent())
    return;
  // Vérifier la présence d'un nouveau badge 
  if ( !rfid.PICC_ReadCardSerial())
    return;
    …
}

4- Enregistrement de l’ID

…
// Enregistrer l'ID du badge (4 octets) 
for (byte i = 0; i < 4; i++) 
{
  nuidPICC[i] = rfid.uid.uidByte[i];
}
…

5- Affichage de l’ID

…
// Affichage de l'ID 
Serial.println("Un badge est détecté");
Serial.println(" L'UID du tag est:");
for (byte i = 0; i < 4; i++) 
{
  Serial.print(nuidPICC[i], HEX);
  Serial.print(" ");
}
Serial.println();
…

6- Re-Initialisation RFID

...
// Re-Init RFID
rfid.PICC_HaltA(); // Halt PICC
rfid.PCD_StopCrypto1(); // Stop encryption on PCD
...

7- Programme complet

#include <SPI.h> // SPI
#include <MFRC522.h> // RFID
#define SS_PIN 10
#define RST_PIN 9
    
// Déclaration 
MFRC522 rfid(SS_PIN, RST_PIN); 
// Tableau contentent l'ID
byte nuidPICC[4];
void setup() 
{ 
  // Init RS232
  Serial.begin(9600);
  // Init SPI bus
  SPI.begin(); 
  // Init MFRC522 
  rfid.PCD_Init(); 
}
 
void loop() 
{
  // Initialisé la boucle si aucun badge n'est présent 
  if ( !rfid.PICC_IsNewCardPresent())
    return;
  // Vérifier la présence d'un nouveau badge 
  if ( !rfid.PICC_ReadCardSerial())
    return;
  // Enregistrer l'ID du badge (4 octets) 
  for (byte i = 0; i < 4; i++) 
  {
    nuidPICC[i] = rfid.uid.uidByte[i];
  }
  
  // Affichage de l'ID 
  Serial.println("Un badge est détecté");
  Serial.println(" L'UID du tag est:");
  for (byte i = 0; i < 4; i++) 
  {
    Serial.print(nuidPICC[i], HEX);
    Serial.print(" ");
  }
  Serial.println();
  // Re-Init RFID
  rfid.PICC_HaltA(); // Halt PICC
  rfid.PCD_StopCrypto1(); // Stop encryption on PCD
}

Programme du contrôle d’accès par un badge

On reprend les mêmes étapes du programme de lecture. En revanche, on garde en mémoire l’ID du badge {0x20, 0x12, 0x23, 0x2B}. Le programme compare en permanent le nouvel ID avec l’ID de base. Si les deux ID sont identiques, on déclenche l’ouverture de la porte, sinon l’alarme après trois tentatives. On fera des tests (voir la vidéo) en utilisant le bon badge ayant le même ID enregistré et un nouveau badge ayant un ID différent. On verra dans la vidéo une démonstration avec 3 et 4 tentatives. Ci-dessous le programme principal du projet.

Nous utiliserons une nouvelle fonction GetAccesState() qui prend  en argument les deux ID (ID enregistré et le nouvel ID), puis elle retourne « 1 » si les deux ID sont identiques et 0 dans le cas contraire. Les variables à l’entrée sont deux tableaux de tailles 4 aux formats byte (la taille du code est égale à 4 octets). Ci-dessous la déclaration de la fonction :

byte GetAccesState(byte *CodeAcces,byte *NewCode) 
{
  byte StateAcces=0; 
  if ((CodeAcces[0]==NewCode[0])&&(CodeAcces[1]==NewCode[1])&&
  (CodeAcces[2]==NewCode[2])&& (CodeAcces[3]==NewCode[3]))
    return StateAcces=1; 
  else
    return StateAcces=0; 
}

Programme principal

#include <SPI.h>
#include <MFRC522.h>
#define SS_PIN 10
#define RST_PIN 9
    
#define AccesFlag_PIN 2
#define Gate_PIN 3
#define Max_Acces 3
byte Count_acces=0; 
byte CodeVerif=0; 
byte Code_Acces[4]={0x20, 0x12, 0x23, 0x2B}; 
MFRC522 rfid(SS_PIN, RST_PIN); // Instance of the class
// Init array that will store new NUID 
byte nuidPICC[4];
void setup() 
{ 
  // Init RS232
  Serial.begin(9600);
  // Init SPI bus
  SPI.begin(); 
  // Init MFRC522 
  rfid.PCD_Init(); 
  // Init LEDs 
  pinMode(AccesFlag_PIN, OUTPUT);
  pinMode(Gate_PIN, OUTPUT);
  
  digitalWrite(AccesFlag_PIN, LOW);
  digitalWrite(Gate_PIN, LOW);
}
 
void loop() 
{
  // Initialisé la boucle si aucun badge n'est présent 
  if ( !rfid.PICC_IsNewCardPresent())
    return;
  // Vérifier la présence d'un nouveau badge 
  if ( !rfid.PICC_ReadCardSerial())
    return;
  // Afffichage 
  Serial.println(F("Un badge est détecté"));
  // Enregistrer l’ID du badge (4 octets) 
  for (byte i = 0; i < 4; i++) {
    nuidPICC[i] = rfid.uid.uidByte[i];
  }
  // Vérification du code 
  CodeVerif= GetAccesState(Code_Acces,nuidPICC); 
  if (CodeVerif!=1)
  {
    Count_acces+=1;
    if(Count_acces==Max_Acces)
    {
     // Dépassement des tentatives (clignotement infinie) 
     while(1)
     {
      digitalWrite(AccesFlag_PIN, HIGH);
      delay(200); 
      digitalWrite(AccesFlag_PIN, LOW);
      delay(200); 
      // Affichage 
      Serial.println("Alarme!");
     }
    }
    else
    {
      // Affichage 
      Serial.println("Code érroné");
    
      // Un seul clignotement: Code erroné 
      digitalWrite(AccesFlag_PIN, HIGH);
      delay(1000); 
      digitalWrite(AccesFlag_PIN, LOW);
    }
  }
  else
  {
    // Affichage 
    Serial.println("Ouverture de la porte");
    
    // Ouverture de la porte & Initialisation 
    digitalWrite(Gate_PIN, HIGH);
    delay(3000); 
    digitalWrite(Gate_PIN, LOW);
    Count_acces=0; 
  }
  // Affichage de l'identifiant 
  Serial.println(" L'UID du tag est:");
  for (byte i = 0; i < 4; i++) 
  {
    Serial.print(nuidPICC[i], HEX);
    Serial.print(" ");
  }
  Serial.println();
  // Re-Init RFID
  rfid.PICC_HaltA(); // Halt PICC
  rfid.PCD_StopCrypto1(); // Stop encryption on PCD
}
byte GetAccesState(byte *CodeAcces,byte *NewCode) 
{
  byte StateAcces=0; 
  if ((CodeAcces[0]==NewCode[0])&&(CodeAcces[1]==NewCode[1])&&
  (CodeAcces[2]==NewCode[2])&& (CodeAcces[3]==NewCode[3]))
    return StateAcces=1; 
  else
    return StateAcces=0; 
}

Téléchargement

 

    Laisser un commentaire

    Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

    Rejoindre la liste d'attente Nous vous informerons lorsque le produit arrivera en stock. Veuillez laisser votre adresse E-mail et la quantité voulue.

    Main Menu

    بحاجة الى مساعدة ؟